<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># $Id: Embed.pm,v 1.2501 $
require 5.002;

package ExtUtils::Embed;
require Exporter;
require FileHandle;
use Config;
use Getopt::Std;
use File::Spec;

#Only when we need them
#require ExtUtils::MakeMaker;
#require ExtUtils::Liblist;

use vars qw(@ISA @EXPORT $VERSION
	    @Extensions $Verbose $lib_ext
	    $opt_o $opt_s 
	    );
use strict;

$VERSION = sprintf("%d.%02d", q$Revision: 1.2505 $ =~ /(\d+)\.(\d+)/);

@ISA = qw(Exporter);
@EXPORT = qw(&amp;xsinit &amp;ldopts 
	     &amp;ccopts &amp;ccflags &amp;ccdlflags &amp;perl_inc
	     &amp;xsi_header &amp;xsi_protos &amp;xsi_body);

#let's have Miniperl borrow from us instead
#require ExtUtils::Miniperl;
#*canon = \&amp;ExtUtils::Miniperl::canon;

$Verbose = 0;
$lib_ext = $Config{lib_ext} || '.a';

sub is_cmd { $0 eq '-e' }

sub my_return {
    my $val = shift;
    if(is_cmd) {
	print $val;
    }
    else {
	return $val;
    }
}

sub is_perl_object {
    $Config{ccflags} =~ /-DPERL_OBJECT/;  
}

sub xsinit { 
    my($file, $std, $mods) = @_;
    my($fh,@mods,%seen);
    $file ||= "perlxsi.c";
    my $xsinit_proto = "pTHXo";

    if (@_) {
       @mods = @$mods if $mods;
    }
    else {
       getopts('o:s:');
       $file = $opt_o if defined $opt_o;
       $std  = $opt_s  if defined $opt_s;
       @mods = @ARGV;
    }
    $std = 1 unless scalar @mods;

    if ($file eq "STDOUT") {
	$fh = \*STDOUT;
    }
    else {
	$fh = new FileHandle "&gt; $file";
    }

    push(@mods, static_ext()) if defined $std;
    @mods = grep(!$seen{$_}++, @mods);

    print $fh &amp;xsi_header();
    print $fh "EXTERN_C void xs_init ($xsinit_proto);\n\n";     
    print $fh &amp;xsi_protos(@mods);

    print $fh "\nEXTERN_C void\nxs_init($xsinit_proto)\n{\n";
    print $fh &amp;xsi_body(@mods);
    print $fh "}\n";

}

sub xsi_header {
    return &lt;&lt;EOF;
#include &lt;EXTERN.h&gt;
#include &lt;perl.h&gt;

EOF
}    

sub xsi_protos {
    my(@exts) = @_;
    my(@retval,%seen);
    my $boot_proto = "pTHXo_ CV* cv";
    foreach $_ (@exts){
        my($pname) = canon('/', $_);
        my($mname, $cname);
        ($mname = $pname) =~ s!/!::!g;
        ($cname = $pname) =~ s!/!__!g;
	my($ccode) = "EXTERN_C void boot_${cname} ($boot_proto);\n";
	next if $seen{$ccode}++;
        push(@retval, $ccode);
    }
    return join '', @retval;
}

sub xsi_body {
    my(@exts) = @_;
    my($pname,@retval,%seen);
    my($dl) = canon('/','DynaLoader');
    push(@retval, "\tchar *file = __FILE__;\n");
    push(@retval, "\tdXSUB_SYS;\n") if $] &gt; 5.002;
    push(@retval, "\n");

    foreach $_ (@exts){
        my($pname) = canon('/', $_);
        my($mname, $cname, $ccode);
        ($mname = $pname) =~ s!/!::!g;
        ($cname = $pname) =~ s!/!__!g;
        if ($pname eq $dl){
            # Must NOT install 'DynaLoader::boot_DynaLoader' as 'bootstrap'!
            # boot_DynaLoader is called directly in DynaLoader.pm
            $ccode = "\t/* DynaLoader is a special case */\n\tnewXS(\"${mname}::boot_${cname}\", boot_${cname}, file);\n";
            push(@retval, $ccode) unless $seen{$ccode}++;
        } else {
            $ccode = "\tnewXS(\"${mname}::bootstrap\", boot_${cname}, file);\n";
            push(@retval, $ccode) unless $seen{$ccode}++;
        }
    }
    return join '', @retval;
}

sub static_ext {
    unless (scalar @Extensions) {
	@Extensions = sort split /\s+/, $Config{static_ext};
	unshift @Extensions, qw(DynaLoader);
    }
    @Extensions;
}

sub ldopts {
    require ExtUtils::MakeMaker;
    require ExtUtils::Liblist;
    my($std,$mods,$link_args,$path) = @_;
    my(@mods,@link_args,@argv);
    my($dllib,$config_libs,@potential_libs,@path);
    local($") = ' ' unless $" eq ' ';
    my $MM = bless {} =&gt; 'MY';
    if (scalar @_) {
       @link_args = @$link_args if $link_args;
       @mods = @$mods if $mods;
    }
    else {
       @argv = @ARGV;
       #hmm
       while($_ = shift @argv) {
	   /^-std$/  &amp;&amp; do { $std = 1; next; };
	   /^--$/    &amp;&amp; do { @link_args = @argv; last; };
	   /^-I(.*)/ &amp;&amp; do { $path = $1 || shift @argv; next; };
	   push(@mods, $_); 
       }
    }
    $std = 1 unless scalar @link_args;
    my $sep = $Config{path_sep} || ':';
    @path = $path ? split(/\Q$sep/, $path) : @INC;

    push(@potential_libs, @link_args)    if scalar @link_args;
    # makemaker includes std libs on windows by default
    if ($^O ne 'MSWin32' and defined($std)) {
	push(@potential_libs, $Config{perllibs});
    }

    push(@mods, static_ext()) if $std;

    my($mod,@ns,$root,$sub,$extra,$archive,@archives);
    print STDERR "Searching (@path) for archives\n" if $Verbose;
    foreach $mod (@mods) {
	@ns = split(/::|\/|\\/, $mod);
	$sub = $ns[-1];
	$root = $MM-&gt;catdir(@ns);
	
	print STDERR "searching for '$sub${lib_ext}'\n" if $Verbose;
	foreach (@path) {
	    next unless -e ($archive = $MM-&gt;catdir($_,"auto",$root,"$sub$lib_ext"));
	    push @archives, $archive;
	    if(-e ($extra = $MM-&gt;catdir($_,"auto",$root,"extralibs.ld"))) {
		local(*FH); 
		if(open(FH, $extra)) {
		    my($libs) = &lt;FH&gt;; chomp $libs;
		    push @potential_libs, split /\s+/, $libs;
		}
		else {  
		    warn "Couldn't open '$extra'"; 
		}
	    }
	    last;
	}
    }
    #print STDERR "\@potential_libs = @potential_libs\n";

    my $libperl;
    if ($^O eq 'MSWin32') {
	$libperl = $Config{libperl};
    }
    else {
	$libperl = (grep(/^-l\w*perl\w*$/, @link_args))[0] || "-lperl";
    }

    my $lpath = File::Spec-&gt;catdir($Config{archlibexp}, 'CORE');
    $lpath = qq["$lpath"] if $^O eq 'MSWin32';
    my($extralibs, $bsloadlibs, $ldloadlibs, $ld_run_path) =
	$MM-&gt;ext(join ' ', "-L$lpath", $libperl, @potential_libs);

    my $ld_or_bs = $bsloadlibs || $ldloadlibs;
    print STDERR "bs: $bsloadlibs ** ld: $ldloadlibs" if $Verbose;
    my $linkage = "$Config{ccdlflags} $Config{ldflags} @archives $ld_or_bs";
    print STDERR "ldopts: '$linkage'\n" if $Verbose;

    return $linkage if scalar @_;
    my_return("$linkage\n");
}

sub ccflags {
    my_return(" $Config{ccflags} ");
}

sub ccdlflags {
    my_return(" $Config{ccdlflags} ");
}

sub perl_inc {
    my $dir = File::Spec-&gt;catdir($Config{archlibexp}, 'CORE');
    $dir = qq["$dir"] if $^O eq 'MSWin32';
    my_return(" -I$dir ");
}

sub ccopts {
   ccflags . perl_inc;
}

sub canon {
    my($as, @ext) = @_;
    foreach(@ext) {
       # might be X::Y or lib/auto/X/Y/Y.a
       next if s!::!/!g;
       s:^(lib|ext)/(auto/)?::;
       s:/\w+\.\w+$::;
    }
    grep(s:/:$as:, @ext) if ($as ne '/');
    @ext;
}

__END__

=head1 NAME

ExtUtils::Embed - Utilities for embedding Perl in C/C++ applications

=head1 SYNOPSIS


 perl -MExtUtils::Embed -e xsinit 
 perl -MExtUtils::Embed -e ccopts 
 perl -MExtUtils::Embed -e ldopts 

=head1 DESCRIPTION

ExtUtils::Embed provides utility functions for embedding a Perl interpreter
and extensions in your C/C++ applications.  
Typically, an application B&lt;Makefile&gt; will invoke ExtUtils::Embed
functions while building your application.  

=head1 @EXPORT

ExtUtils::Embed exports the following functions:

xsinit(), ldopts(), ccopts(), perl_inc(), ccflags(), 
ccdlflags(), xsi_header(), xsi_protos(), xsi_body()

=head1 FUNCTIONS

=over

=item xsinit()

Generate C/C++ code for the XS initializer function.

When invoked as C&lt;`perl -MExtUtils::Embed -e xsinit --`&gt;
the following options are recognized:

B&lt;-o&gt; E&lt;lt&gt;output filenameE&lt;gt&gt; (Defaults to B&lt;perlxsi.c&gt;)

B&lt;-o STDOUT&gt; will print to STDOUT.

B&lt;-std&gt; (Write code for extensions that are linked with the current Perl.)

Any additional arguments are expected to be names of modules
to generate code for.

When invoked with parameters the following are accepted and optional:

C&lt;xsinit($filename,$std,[@modules])&gt;

Where,

B&lt;$filename&gt; is equivalent to the B&lt;-o&gt; option.

B&lt;$std&gt; is boolean, equivalent to the B&lt;-std&gt; option.  

B&lt;[@modules]&gt; is an array ref, same as additional arguments mentioned above.

=item Examples


 perl -MExtUtils::Embed -e xsinit -- -o xsinit.c Socket


This will generate code with an B&lt;xs_init&gt; function that glues the perl B&lt;Socket::bootstrap&gt; function 
to the C B&lt;boot_Socket&gt; function and writes it to a file named F&lt;xsinit.c&gt;.

Note that B&lt;DynaLoader&gt; is a special case where it must call B&lt;boot_DynaLoader&gt; directly.

 perl -MExtUtils::Embed -e xsinit


This will generate code for linking with B&lt;DynaLoader&gt; and 
each static extension found in B&lt;$Config{static_ext}&gt;.
The code is written to the default file name B&lt;perlxsi.c&gt;.


 perl -MExtUtils::Embed -e xsinit -- -o xsinit.c -std DBI DBD::Oracle


Here, code is written for all the currently linked extensions along with code
for B&lt;DBI&gt; and B&lt;DBD::Oracle&gt;.

If you have a working B&lt;DynaLoader&gt; then there is rarely any need to statically link in any 
other extensions.

=item ldopts()

Output arguments for linking the Perl library and extensions to your
application.

When invoked as C&lt;`perl -MExtUtils::Embed -e ldopts --`&gt;
the following options are recognized:

B&lt;-std&gt; 

Output arguments for linking the Perl library and any extensions linked
with the current Perl.

B&lt;-I&gt; E&lt;lt&gt;path1:path2E&lt;gt&gt;

Search path for ModuleName.a archives.  
Default path is B&lt;@INC&gt;.
Library archives are expected to be found as 
B&lt;/some/path/auto/ModuleName/ModuleName.a&gt;
For example, when looking for B&lt;Socket.a&gt; relative to a search path, 
we should find B&lt;auto/Socket/Socket.a&gt;  

When looking for B&lt;DBD::Oracle&gt; relative to a search path,
we should find B&lt;auto/DBD/Oracle/Oracle.a&gt;

Keep in mind that you can always supply B&lt;/my/own/path/ModuleName.a&gt;
as an additional linker argument.

B&lt;--&gt;  E&lt;lt&gt;list of linker argsE&lt;gt&gt;

Additional linker arguments to be considered.

Any additional arguments found before the B&lt;--&gt; token 
are expected to be names of modules to generate code for.

When invoked with parameters the following are accepted and optional:

C&lt;ldopts($std,[@modules],[@link_args],$path)&gt;

Where:

B&lt;$std&gt; is boolean, equivalent to the B&lt;-std&gt; option.  

B&lt;[@modules]&gt; is equivalent to additional arguments found before the B&lt;--&gt; token.

B&lt;[@link_args]&gt; is equivalent to arguments found after the B&lt;--&gt; token.

B&lt;$path&gt; is equivalent to the B&lt;-I&gt; option.

In addition, when ldopts is called with parameters, it will return the argument string
rather than print it to STDOUT.

=item Examples


 perl -MExtUtils::Embed -e ldopts


This will print arguments for linking with B&lt;libperl.a&gt;, B&lt;DynaLoader&gt; and 
extensions found in B&lt;$Config{static_ext}&gt;.  This includes libraries
found in B&lt;$Config{libs}&gt; and the first ModuleName.a library
for each extension that is found by searching B&lt;@INC&gt; or the path 
specified by the B&lt;-I&gt; option.  
In addition, when ModuleName.a is found, additional linker arguments
are picked up from the B&lt;extralibs.ld&gt; file in the same directory.


 perl -MExtUtils::Embed -e ldopts -- -std Socket


This will do the same as the above example, along with printing additional arguments for linking with the B&lt;Socket&gt; extension.


 perl -MExtUtils::Embed -e ldopts -- DynaLoader


This will print arguments for linking with just the B&lt;DynaLoader&gt; extension
and B&lt;libperl.a&gt;.


 perl -MExtUtils::Embed -e ldopts -- -std Msql -- -L/usr/msql/lib -lmsql


Any arguments after the second '--' token are additional linker
arguments that will be examined for potential conflict.  If there is no
conflict, the additional arguments will be part of the output.  


=item perl_inc()

For including perl header files this function simply prints:

 -I$Config{archlibexp}/CORE  

So, rather than having to say:

 perl -MConfig -e 'print "-I$Config{archlibexp}/CORE"'

Just say:

 perl -MExtUtils::Embed -e perl_inc

=item ccflags(), ccdlflags()

These functions simply print $Config{ccflags} and $Config{ccdlflags}

=item ccopts()

This function combines perl_inc(), ccflags() and ccdlflags() into one.

=item xsi_header()

This function simply returns a string defining the same B&lt;EXTERN_C&gt; macro as
B&lt;perlmain.c&gt; along with #including B&lt;perl.h&gt; and B&lt;EXTERN.h&gt;.  

=item xsi_protos(@modules)

This function returns a string of B&lt;boot_$ModuleName&gt; prototypes for each @modules.

=item xsi_body(@modules)

This function returns a string of calls to B&lt;newXS()&gt; that glue the module B&lt;bootstrap&gt;
function to B&lt;boot_ModuleName&gt; for each @modules.

B&lt;xsinit()&gt; uses the xsi_* functions to generate most of it's code.

=back

=head1 EXAMPLES

For examples on how to use B&lt;ExtUtils::Embed&gt; for building C/C++ applications
with embedded perl, see L&lt;perlembed&gt;.

=head1 SEE ALSO

L&lt;perlembed&gt;

=head1 AUTHOR

Doug MacEachern E&lt;lt&gt;F&lt;dougm@osf.org&gt;E&lt;gt&gt;

Based on ideas from Tim Bunce E&lt;lt&gt;F&lt;Tim.Bunce@ig.co.uk&gt;E&lt;gt&gt; and
B&lt;minimod.pl&gt; by Andreas Koenig E&lt;lt&gt;F&lt;k@anna.in-berlin.de&gt;E&lt;gt&gt; and Tim Bunce.

=cut

</pre></body></html>