***************************************************************************
*               box 3-dimensional function
* more, garbow, and hillstrom, acm toms vol. 7 no. 1 (march 1981) 17-41
***************************************************************************

      subroutine getfun( x, n, f, m, ftf, fj, lfj, g, mode)

      implicit double precision (a-h,o-z)

      integer            n, m, lfj, mode

      double precision   x(n), f(m), ftf, fj(lfj,n), g(n)

      integer            nprob, nprobs, nstart, nstrts
      common /PROBLM/    nprob, nprobs, nstart, nstrts

      integer            nout
      common /IOUNIT/    nout

      logical            lf, lj

      integer            na, nb, nc, nd, nt, nh

      integer            i, j

      double precision   x1, x2, x3
      double precision   e1, e2, ti, t3

      double precision   ddot

      intrinsic          dble, exp

      double precision   zero, one, point1, ten
      parameter         (zero = 0.d0, one = 1.d0)
      parameter         (point1 = .1d0, ten = 10.d0)

*=======================================================================

      if (mode .eq.  0)  goto    20
      if (mode .eq. -1)  goto    10
      if (mode .eq. -2)  goto    30

      x1 = x(1)
      x2 = x(2)
      x3 = x(3)

      na = mode / 1000
      nt = mode - na*1000
      nb = nt / 100
      nh = nt - nb*100
      nc = nh / 10
      nd = nh - nc*10

      lf = (na .ne. 0) .or. (nb .ne. 0) .or. (nd .ne. 0)
      lj = (nc .ne. 0) .or. (nd .ne. 0)

      if (lf .and. lj)  goto 300
      if (lf)           goto 100
      if (lj)           goto 200

*-----------------------------------------------------------------------

  10  continue

      nprobs = 1
      nstrts = 1

      n      = 3
      m      = 10

      if (nout .gt. 0)  write( nout, 9999)  n, m

      return

*-----------------------------------------------------------------------

   20 continue

      x(1) =  0.d0
      x(2) = 10.d0
      x(3) = 20.d0

      return

*-----------------------------------------------------------------------

   30 continue

      ftf = zero

      return

*-----------------------------------------------------------------------

 100  continue

      do 110 i = 1, m
        ti   = dble(i)*point1
        e1   = exp(-ti*x1)
        e2   = exp(-ti*x2)
        t3   = exp(-ti) - exp(-ti*ten)
        f(i) =  e1 - e2 - x3*t3
 110  continue

      if (nb .ne. 0)  ftf = ddot( m, f, 1, f, 1)

      return

 200  continue

      do 210 i = 1, m
        ti = dble(i)*point1
        e1 = exp(-ti*x1)
        e2 = exp(-ti*x2)
        t3 = exp(-ti) - exp(-ti*ten)
        fj( i, 1) = -ti*e1
        fj( i, 2) =  ti*e2
        fj( i, 3) = -t3
 210  continue

      return

 300  continue

      do 310 i = 1, m
        ti = dble(i)*point1
        e1 = exp(-ti*x1)
        e2 = exp(-ti*x2)
        t3 = exp(-ti) - exp(-ti*ten)
        f(i) =  e1 - e2 - x3*t3
        fj( i, 1) = -ti*e1
        fj( i, 2) =  ti*e2
        fj( i, 3) = -t3
 310  continue

      if (nb .ne. 0)  ftf = ddot( m, f, 1, f, 1)

      if (nd .eq. 0)  return

      do 320 j = 1, n
        g(j) = ddot( m, fj( 1, j), 1, f, 1)
 320  continue

      return

9999  format(/'1',70('=')//,
     *' box 3-d function (more et al.) '//,
     *'        number of variables =', i4, '  (     3  )'/,
     *'        number of functions =', i4, '  (  >= 3  )'//,
     *        ' ',70('=')/)
      end

************************************************************************
************************************************************************

      subroutine dfjdxk ( k, x, n, dfj, ldfj, m, nonzro)

      implicit double precision (a-h,o-z)

      integer            k, n, ldfj, m, nonzro(n)

      double precision   x(n), dfj(ldfj,n)

      integer            i, j

      intrinsic          dble, exp

      double precision   zero, point1
      parameter         (zero = 0.d0, point1 = .1d0)

*=======================================================================

      goto ( 210, 220, 230), k

 210  continue

      x1 = x(1)
      nonzro(1) = 1
      nonzro(2) = 0
      nonzro(3) = 0
      do 215 i = 1, m
        ti = point1*dble(i)
        dfj( i, 1) = ti*ti*exp(-ti*x1)
        dfj( i, 2) = zero
        dfj( i, 3) = zero
 215  continue

      return

 220  continue

      x2 = x(2)
      nonzro(1) = 0
      nonzro(2) = 1
      nonzro(3) = 0
      do 225 i = 1, m
        ti = point1*dble(i)
        dfj( i, 1) = zero
        dfj( i, 2) = ti*ti*exp(-ti*x2)
        dfj( i, 3) = zero
 225  continue

      return

 230  continue

      do 235 j = 1, n
        nonzro(j) = 0
        call dcopy( m, zero, 0, dfj( 1, j), 1)
 235  continue

      return

      end

************************************************************************
************************************************************************

      subroutine dfkdij( k, x, n, hess, lhess, linear)

      implicit double precision (a-h,o-z)

      logical            linear

      integer            k, n, lhess

      double precision   x(n), hess(lhess,n)

      double precision   tk, ts

      intrinsic          dble, exp

      double precision   zero, point1
      parameter         (zero = 0.d0, point1 = .1d0)

*=======================================================================

      linear = .false.

      tk = point1*dble(k)
      ts = tk*tk
      hess(1,1) = ts*exp(-tk*x(1))
      hess(1,2) = zero
      hess(1,3) = zero
      hess(2,1) = zero
      hess(2,2) = ts*exp(-tk*x(2))
      hess(2,3) = zero
      hess(3,1) = zero
      hess(3,2) = zero
      hess(3,3) = zero

      return
      end