      subroutine ctslc(a,x,r,m,l,lda)
      integer m,l,lda
      complex a(lda,l),x(m,l),r(1)
c
c     ctslc solves the complex linear system
c     a * x = b
c     with the ct - matrix a .
c
c     on entry
c
c        a       complex(2*m - 1,l)
c                the first row of blocks of the ct - matrix .
c                each block is represented by its first row
c                followed by its first column beginning with the
c                second element. on return a has been destroyed .
c
c        x       complex(m*l)
c                the right hand side vector b .
c
c        r       complex(max(2*m - 2,2*l))
c                a work vector .
c
c        m       integer
c                the order of the blocks of the matrix a .
c
c        l       integer
c                the number of blocks in a row or column
c                of the matrix a .
c
c        lda     integer
c                the leading dimension of the array a .
c
c     on return
c
c        x       the solution vector .
c
c     toeplitz package. this version dated 07/23/82 .
c
c     subroutines and functions
c
c        toeplitz package ... salwc,tslc
c        fortran ... float
c
c     internal variables
c
      integer i1,i2
      real rl
c
      rl = float(l)
c
c     reduce the ct - matrix to a block-diagonal matrix
c     by the inverse discrete fourier transformation .
c
      call salwc(a,r,r(l+1),2*m - 1,l,lda,-1)
c
c     compute the discrete fourier transformation of
c     the right hand side vector .
c
      call salwc(x,r,r(l+1),m,l,m,1)
c
c     solve the block-diagonal system, blocks of which
c     are t - matrices .
c
      do 10 i2 = 1, l
         call tslc(a(1,i2),x(1,i2),r,m)
   10 continue
c
c     compute the solution of the given system by
c     the inverse discrete fourier transformation .
c
      call salwc(x,r,r(l+1),m,l,m,-1)
c
      do 30 i2 = 1, l
         do 20 i1 = 1, m
            x(i1,i2) = x(i1,i2)/rl
   20    continue
   30 continue
      return
      end