#
# Additional data columns can be used to hold text rotation or color
# for plot style "with labels"
#
$Data <<EOD
1 one -30
2 two -60
3 three -90
4 four -120
5 five -150
6 six -180
7 seven -210
8 eight -240
9 nine -270
10 ten -300
11 eleven -330
12 twelve -360
EOD

set angle degrees
unset key
set title "variable color and orientation in plotstyle 'with labels'" offset 0,-2

set xrange [0:13]
set yrange [0:13]
set xtics 1,1,12 nomirror
set ytics 1,1,12 nomirror
set border 3

plot $Data using 1:1:2:3:0 with labels rotate variable tc variable font ",20"

pause -1 "<cr> to continue"
reset
